TapHome
Społeczność Beta Integracja HVAC

Daikin FCBAG Modbus RTU

Daikin FCBAG to wtykowy moduł Modbus RTU do klimakonwektorów (fan coil) Daikin FWT-HT i FWT-HTV, podłączony do TapHome przez RS-485. Włącza i wyłącza jednostkę, ustawia tryb pracy, temperaturę zadaną, położenie żaluzji nawiewu i prędkość wentylatora oraz odczytuje temperaturę pomieszczenia, kody błędów Daikin i błąd czujnika pokojowego. Modbus włącza się przełącznikiem DIP na płycie głównej, adres slave na module.

Modbus RTU5 urządzeńRewizja 1.0 Ostatnia aktualizacja: 12 listopada 2026

Dodane przez Architechnik Kft.

Daikin FCBAG Modbus RTU

Import do aplikacji TapHomeSprzęt › Modbus › Dodaj z szablonu

Pobierz szablon
Na tej stronie

Poradnik integracji

Daikin FCBAG to opcjonalny moduł wtykowy Modbus RTU do naściennych klimakonwektorów wodnych (fan coil) Daikin FWT-HT i FWT-HTV. Montuje się go w przeznaczonym gnieździe w skrzynce sterowniczej jednostki wewnętrznej, łączy z płytą główną jednostki krótką wiązką przewodów i udostępnia jednostkę na magistrali RS-485. Szablon łączy TapHome bezpośrednio z tą magistralą — inna bramka nie jest potrzebna — i obejmuje włączanie i wyłączanie jednostki, tryb pracy, temperaturę pomieszczenia i temperaturę zadaną, położenie żaluzji nawiewu, prędkość wentylatora oraz kody błędów jednostki.

Nazwy urządzeń w szablonie są po węgiersku. Poniżej każde urządzenie jest nazwane dokładnie tak, jak pojawia się po imporcie, a po nim podane jest jego znaczenie, na przykład Klíma (włączanie/wyłączanie jednostki).

Podłączenie sprzętowe

Instalację może wykonać wyłącznie wykwalifikowana osoba. Przed otwarciem skrzynki sterowniczej wyłącz jednostkę i odłącz wszystkie źródła zasilania.

Moduł FCBAG

Układ płytki modułu Daikin FCBAG: zacisk TB_RS485, złącze CN_MODBUS_MODULAR_1, przełącznik DIP_RS485, diody TX i RX
ElementFunkcja
TB_RS485Zacisk RS-485 (A, B) dla mastera Modbus i kolejnych modułów FCBAG
CN_MODBUS_MODULAR_1Złącze wiązki prowadzącej do CN_MODBUS_MODULAR na płycie głównej jednostki
DIP_RS485Adres slave jednostki
TX_LED (żółta)Trwa wysyłanie danych
RX_LED (czerwona)Trwa odbiór danych

W opakowaniu znajdują się moduł, 10-żyłowa wiązka przewodów (100 mm) do płyty głównej i instrukcja. Według Daikin moduł można stosować wyłącznie z klimakonwektorami wyprodukowanymi przez Daikin Manufacturing.

Montaż modułu w jednostce

  1. Wyłącz jednostkę i zdejmij metalową pokrywę skrzynki sterowniczej.
  2. Włóż moduł FCBAG do przeznaczonego gniazda i wsuń go do końca w zaczep.
  3. Połącz wiązką CN_MODBUS_MODULAR_1 na module z CN_MODBUS_MODULAR na płycie głównej (złącze oznaczone „Accessory: Modbus (FCBAG)” w instrukcji instalacji jednostki).
  4. Poprowadź kabel RS-485 tak, jak pokazuje instrukcja modułu.
  5. Ustaw przełączniki DIP (zobacz Konfiguracja poniżej) i zamknij skrzynkę sterowniczą metalową pokrywą.

Okablowanie RS-485

Podłącz A i B zacisku TB_RS485 do A i B magistrali RS-485 TapHome. Kilka jednostek łączy się szeregowo od jednego TB_RS485 do następnego — instrukcja modułu pokazuje do 15 jednostek na jednej magistrali za masterem Modbus.

PołączenieKabelMaks. długość
Moduł FCBAG – master Modbus (TapHome)ekranowana skrętka 24 AWG, impedancja falowa 100 Ω1000 m
Moduł FCBAG – płyta główna10-żyłowa wiązka przewodów (w zestawie)100 mm

Konfiguracja

Parametry komunikacji ustawia się na dwóch przełącznikach DIP: DIP_Config na płycie głównej jednostki i DIP_RS485 na module FCBAG. Modbus pozostaje wyłączony, dopóki pin 1 przełącznika DIP_Config nie zostanie ustawiony na ON.

Tabela konfiguracji Daikin FCBAG: piny DIP_Config do włączenia Modbus, prędkości transmisji, bitu stopu i parzystości oraz piny DIP_RS485 adresu slave

DIP_Config na płycie głównej

PinFunkcjaOFFONDla tego szablonu
1ModbusWyłączonyWłączonyON
2Prędkość transmisji9600 bps19200 bpsOFF (9600)
3Bit stopu1 (z parzystością)2 (bez parzystości)OFF
4Parzystość (tylko gdy pin 3 jest na OFF)Parzysta (Even)Nieparzysta (Odd)OFF (Even)
5Zarezerwowany w instrukcji modułu——zobacz uwagę

Instrukcja instalacji jednostki używa pinu 5 przełącznika DIP_Config do włączenia bezpotencjałowego wejścia wł./wył. (TB_ON/OFF). Nie należy on do ustawień Modbus — ustaw go tak, jak wymaga ta funkcja.

Adres slave (DIP_RS485 na module)

Piny 1–4 przełącznika DIP_RS485 ustawiają adres slave binarnie: pin 1 = 1, pin 2 = 2, pin 3 = 4, pin 4 = 8 (adres to suma pinów ustawionych na ON). Prawidłowe są adresy 1–15; 0 (wszystkie OFF) wyłącza komunikację Modbus. Pin 5 jest zarezerwowany. Każda jednostka na magistrali potrzebuje własnego adresu, a szablon obejmuje jedną jednostkę — przy kilku jednostkach importuje się go raz dla każdej jednostki z jej adresem.

Domyślny Slave ID szablonu to 2 — tylko pin 2 na ON. Instrukcja modułu (strona „Unit configuration”) pokazuje położenia przełączników dla wszystkich adresów 1–15.

Parametry komunikacji

ParametrWartość
Prędkość transmisji9600
ParzystośćParzysta (Even)
Bity danych8
Bity stopu1
Slave ID2 (parametr importu Modbus Slave ID)

W TapHome szablon importuje się na interfejsie Modbus RTU tej magistrali RS-485 z powyższymi parametrami, a parametr importu Modbus Slave ID ustawia się na adres z DIP_RS485.

Możliwości urządzenia

Numery rejestrów poniżej są zgodne z instrukcją modułu: rejestry input 3xxxx są odczytywane, rejestry holding 4xxxx są zapisywane. Polecenia, które zmieniają tylko część rejestru 42001, najpierw go odczytują i zapisują z powrotem ze zmienioną tylko tą częścią, dzięki czemu włączanie/wyłączanie, żaluzja i prędkość wentylatora nie nadpisują się nawzajem.

Włączanie/wyłączanie

Klíma (włączanie/wyłączanie jednostki) — odczytuje bit 0 rejestru input 32001 i zapisuje bit 0 rejestru holding 42001. Jego atrybuty serwisowe pokazują aktualną prędkość wentylatora (Ventilátor sebesség) i położenie żaluzji (Légirány (swing)). Atrybut żaluzji odczytuje tylko bity 8–9, więc pozycje 4, 5 i Swing pokazuje jako inne wartości — pełną wartość pokazuje urządzenie Lamella állás.

Tryb pracy

Üzemmód (tryb pracy) — odczytuje rejestr input 32002 i zapisuje rejestr holding 42002:

WartośćStan w TapHomeZnaczenie
0VentilátorWentylator
1FűtésGrzanie
2HűtésChłodzenie
3AutoAuto
7SzárazOsuszanie

Temperatura

Hőmérséklet (termostat):

  • temperatura pomieszczenia z rejestru input 32005, podzielona przez 10,
  • temperatura zadana odczytywana z rejestru input 32003 (podzielona przez 10) i zapisywana do rejestru holding 42003 (pomnożona przez 10),
  • zakres temperatury zadanej w TapHome 16–32 °C.

Termostat zgłasza też dwa błędy:

  • Meghibásodás (awaria jednostki) — gdy ustawiony jest bit 9 rejestru input 32004 (kod błędu). Tekst pokazuje kod błędu Daikin: literę z bitów 8–12 (1 = A, 2 = C, 3 = E, 4 = H, 5 = F, 6 = J, 7 = L, 8 = P, 9 = U), a po niej liczbę z bitów 0–3.
  • Szobahőmérséklet-érzékelő hiba (błąd czujnika temperatury pomieszczenia) — gdy ustawiony jest bit 8 rejestru input 32006.

Żaluzja i wentylator

  • Lamella állás (położenie żaluzji nawiewu) — bity 8–10 rejestru 32001, zapisywane do bitów 8–10 rejestru 42001: Megáll (stop), 1. pozíció … 5. pozíció (pozycje 1–5) i Swing.
  • Ventilátor sebesség (prędkość wentylatora) — bity 12–14 rejestru 32001, zapisywane do bitów 12–14 rejestru 42001: Alacsony (niska), Közép-alacsony (średnio-niska), Közepes (średnia), Közép-magas (średnio-wysoka), Magas (wysoka) i Auto.

Instrukcja modułu wymienia też Disable Handset Control (42010), Force Compressor / Valve Off (42011), temperaturę wymiennika jednostki wewnętrznej (32201), stan modułu i połączenia (30001, 30002) oraz limity temperatury zadanej jednostki (31002, 31003). Nie są one częścią tego szablonu.

Rozwiązywanie problemów

Diody LED na module pokazują stan magistrali: RX_LED (czerwona) dla odbioru, TX_LED (żółta) dla wysyłania.

  • Brak komunikacji, RX_LED świeci światłem ciągłym, ale nie miga, TX_LED nie miga: A i B na TB_RS485 są zamienione albo jeden z nich nie jest podłączony. Sprawdź okablowanie na TB_RS485.
  • Brak komunikacji, RX_LED miga, TX_LED nie miga: ustawienie DIP_Config na płycie głównej jest nieprawidłowe — pin 1 (Modbus) musi być na ON. Sprawdź też, czy DIP_RS485 nie jest ustawiony na 0 i czy zgadza się z Modbus Slave ID szablonu.
  • Wartości są odczytywane, ale jednostka nie reaguje na polecenia (obie diody migają): DIP_Config nie zgadza się z ustawieniami komunikacji interfejsu TapHome. Z pinem 2 na ON moduł pracuje z prędkością 19200 Bd, z pinem 3 na ON używa 2 bitów stopu bez parzystości, z pinem 4 na ON parzystości nieparzystej (odd).

Dostępne urządzenia 5

Te urządzenia pojawią się w TapHome po imporcie.

Daikin FCBAG modul Moduł
Klíma Przełącznik
Wartości / Stany: ON · OFF

Klíma

Odczyt stanu przełącznika
GETBIT(MODBUSR(A, 2000, UInt16), 0)
Zapis stanu przełącznika
VAR reg := MODBUSR(H, 2000, UInt16);
reg := SETBIT(reg, 0, St);
MODBUSWNE(H, 2000, UInt16, reg);
Atrybuty serwisowe
Ventilátor sebesség
SWITCH(GETBITS(MODBUSR(A, 2000, UInt16), 12, 3), 1, "Alacsony", 2, "Közép-alacsony", 3, "Közepes", 4, "Közép-magas", 5, "Magas", 7, "Auto", "Ismeretlen")
Légirány (swing)
SWITCH(GETBITS(MODBUSR(A, 2000, UInt16), 8, 2), 0, "Megáll", 1, "1. pozíció", 2, "2. pozíció", 3, "3. pozíció", 4, "4. pozíció", 5, "5. pozíció", 7, "Swing", "Ismeretlen")
Üzemmód Przełącznik wielowartościowy
Wartości / Stany: Ventilátor · Fűtés · Hűtés · Auto · Száraz

Üzemmód

Odczyt stanu przełącznika
MODBUSR(A, 2001, UInt16)
Zapis stanu przełącznika
MODBUSWNE(H, 2001, UInt16, Mu)
Hőmérséklet Termostat

Hőmérséklet

Odczyt temperatury
MODBUSR(A, 2004, Int16)/10
Odczyt temperatury zadanej
MODBUSR(A, 2002, Int16)/10
Zapis temperatury zadanej
MODBUSWNE(H, 2002, Int16, Se*10)
Odczyt (moduł)
VAR errorReg := MODBUSR(A, 2003, UInt16);
IF(GETBIT(errorReg, 9))
  VAR upper := GETBITS(errorReg, 8, 5);
  VAR lower := GETBITS(errorReg, 0, 4);
  VAR letter := SWITCH(upper, 1, "A", 2, "C", 3, "E", 4, "H", 5, "F", 6, "J", 7, "L", 8, "P", 9, "U", "?");
  ADDERROR(1, "Meghibásodás: " + letter + TOSTRING(lower, "F0"));
END
VAR sensorReg := MODBUSR(A, 2005, UInt16);
IF(GETBIT(sensorReg, 8))
  ADDERROR(2, "Szobahőmérséklet-érzékelő hiba");
END
Lamella állás Przełącznik wielowartościowy
Wartości / Stany: Megáll · 1. pozíció · 2. pozíció · 3. pozíció · 4. pozíció · 5. pozíció · Swing

Lamella állás

Odczyt stanu przełącznika
GETBITS(MODBUSR(A, 2000, UInt16), 8, 3)
Zapis stanu przełącznika
VAR reg := MODBUSR(H, 2000, UInt16);
reg := SETBITS(reg, 8, 3, Mu);
MODBUSW(H, 2000, UInt16, reg);
Ventilátor sebesség Przełącznik wielowartościowy
Wartości / Stany: Alacsony · Közép-alacsony · Közepes · Közép-magas · Magas · Auto

Ventilátor sebesség

Odczyt stanu przełącznika
GETBITS(MODBUSR(A, 2000, UInt16), 12, 3)
Zapis stanu przełącznika
VAR reg := MODBUSR(H, 2000, UInt16);
reg := SETBITS(reg, 12, 3, Mu);
MODBUSW(H, 2000, UInt16, reg);
Połączenie: Modbus RTU • 9600 baud• 8E1 • Slave ID: $[SlaveId]

Parametry importu

Te wartości podajesz podczas importu pliku XML.

Pytanie w aplikacjiDomyślnie
Modbus Slave ID2

Znalazłeś problem z tym szablonem urządzenia?

Napisz nam, co nie działa, czego brakuje lub jak powinien zachowywać się szablon. Twoja opinia pomaga nam utrzymać katalog dokładnym.

Szablon · portal TapHome Daikin FCBAG Modbus RTU Otwórz ten szablon w portalu klienta, aby zastosować go w swoim domu, lub zaproponuj modyfikację i wyślij ją z powrotem do katalogu. Modbus RTU Zobacz w portalu TapHome